;Autor: Rudi

EnableExplicit

Define EventID

Structure NOTIFYICONDATA_
  cbSize.l
  hwnd.i
  uId.l
  uFlags.l
  uCallbackMessage.l
  hIcon.i
  StructureUnion
    szTip.c[64]
    szTipEx.c[128]
  EndStructureUnion
  dwState.l
  dwStateMask.l
  szInfo.s{256}
  StructureUnion
    uTimeout.l
    uVersion.l
  EndStructureUnion
  szInfoTitle.c[64]
  dwInfoFlags.l
  guidItem.GUID
  hBalloonIcon.i
EndStructure

Procedure SysTrayIconBalloon(uId, hWindow, Title$, Message$, timeOut, flags)
  Protected nId.NOTIFYICONDATA_
  If OSVersion() >= #PB_OS_Windows_Vista
    nId\cbSize = SizeOf(NOTIFYICONDATA_)
  ElseIf OSVersion() >= #PB_OS_Windows_XP
    nId\cbSize = 504
  ElseIf OSVersion() >= #PB_OS_Windows_2000
    nId\cbSize = 488
  Else
    nId\cbSize = 88
  EndIf
  If nId\cbSize
    nId\uVersion    = 4
    Shell_NotifyIcon_(#NIM_SETVERSION, @nId)
    nId\uId         = uId
    nId\hwnd        = hWindow
    nId\dwInfoFlags = flags
    nId\uFlags      = #NIF_INFO
    nId\uTimeout    = timeOut
    nId\szInfo      = Message$
    PokeS(@nId\szInfo, Message$)
    PokeS(@nId\szInfoTitle, Title$)
    ProcedureReturn Shell_NotifyIcon_(#NIM_MODIFY, @nId)
  EndIf
  ProcedureReturn #False
EndProcedure

If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  AddSysTrayIcon(0, WindowID(0), ExtractIcon_(0,"explorer.exe",3))
  SysTrayIconBalloon(0, WindowID(0),"BalloonTip 1!","BalloonTip",100,#NIIF_INFO)
  ;SysTrayIconBalloon(0, WindowID(0),"BalloonTip 2!","BalloonTip",100,#NIIF_WARNING)
  ;SysTrayIconBalloon(0, WindowID(0),"","",100,#NIIF_INFO);ToolTip ausblenden
  
  Repeat
    EventID=WaitWindowEvent()
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf